MODULE CHKCNV_SUB
CONTAINS
SUBROUTINE CHKCNV ( FAIL, ERRMSG )
!
! VERSION
!   04NOV26 AD Original.
!
! DESCRIPTION
!   Check convolved output resolution consistent with fine grid
!   Called once by DRVCHK if AVG or ILS flags enabled. 
!
! VARIABLE KINDS
    USE KIND_DAT
!
! GLOBAL DATA
    USE SPCCOM_DAT ! Spectral range data
    USE FINCOM_DAT, ONLY: NOMFIN ! Nominal No.pts/cm-1 for fine mesh
    USE FLGCOM_DAT, ONLY: GHZFLG ! T = Use GHz spectral axis, F = Wavenumbe
!
! SUBROUTINES
    USE C11INT_FNC ! Write integer as left-adjusted string
    USE WRTLOG_SUB ! Write text message to log file
!
  IMPLICIT NONE 
!
! ARGUMENTS
    LOGICAL,       INTENT(OUT) :: FAIL   ! Set TRUE if a fatal error is detected
    CHARACTER(80), INTENT(OUT) :: ERRMSG ! Error message written if FAIL is TRUE
!
! LOCAL CONSTANTS
    REAL(R4), PARAMETER :: RESTOL = 0.001 ! Frac.allowed for integer factor
!
! LOCAL VARIABLES
    LOGICAL       :: FIRST = .TRUE. ! T=first value of SPC%WNR found
    INTEGER(I4)   :: IFAC    ! Nearest integer to ratio WNR/(fine grid)
    INTEGER(I4)   :: ISPC    ! Counter for spectral ranges
    REAL(R4)      :: RESFAC  ! Actual value of ratio WNR/(fine grid)
    REAL(R8)      :: WNRPRV = -1.0D0 ! Value of WNR from previous spectral range
    CHARACTER(80) :: MESSGE  ! Text message for Log file
 !
! EXECUTABLE CODE -------------------------------------------------------------
!
  DO ISPC = 1, NSPC
    IF ( SPC(ISPC)%WNR .EQ. WNRPRV ) CYCLE   ! Same resln as previous
    WNRPRV = SPC(ISPC)%WNR
!
! Ratio of output spacing to fine-grid spacing
    RESFAC = NOMFIN * SNGL ( SPC(ISPC)%WNR )
!
! Factor that will be used in adjustment of output spacing
    IFAC = NINT ( RESFAC ) 
!
! With GHz output SPC%WNR will not be a convenient multiple of fine grid
! so just check that it rounds up to at least 1 
    IF ( GHZFLG ) THEN
      IF ( IFAC .EQ. 0 ) THEN
        FAIL = .TRUE.
        ERRMSG = 'F-CHKCNV: Output spectral grid spacing less than fine grid'
        RETURN
      END IF
      RESFAC = IFAC  ! To avoid failing test for integer multiple
    END IF
!
! Normally expect all output spectral ranges to be on the same resolution
! but if different add a line to log file stating new range now being checked
    IF ( .NOT. FIRST ) THEN
      MESSGE = 'I-CHKCNV: Spectral range' // TRIM(SPC(ISPC)%LAB) // '...' 
      CALL WRTLOG ( MESSGE )
    END IF
!
    IF ( ABS ( IFAC - RESFAC ) .GT. RESTOL ) THEN
      FAIL = .TRUE.
      ERRMSG = 'F-CHKCNV: Output spectral grid spacing is not ' &
               // 'an integer multiple of fine grid'
      RETURN
    ELSE IF ( IFAC .EQ. 1 ) THEN
      CALL WRTLOG ( 'W-CHKCNV: Convolved output grid same as fine grid' )
    ELSE
      MESSGE = 'I-CHKCNV: Convolved output grid points represent ' &
               // TRIM(C11INT(IFAC)) // ' fine grid points' 
      CALL WRTLOG ( MESSGE )
    END IF
    FIRST = .FALSE.
  END DO
!
  FAIL = .FALSE.
!
END SUBROUTINE CHKCNV
END MODULE CHKCNV_SUB

